mirror of
git://git.sv.gnu.org/coreutils.git
synced 2026-03-04 03:55:51 +02:00
feb302b9f2
Use implementation from Albert Chin, with some comments/corrections by Stepan Kasal and myself.
43 lines
1.7 KiB
Plaintext
43 lines
1.7 KiB
Plaintext
# socklen.m4 serial 2
|
|
dnl Copyright (C) 2005 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Albert Chin.
|
|
|
|
dnl Check for socklen_t: historically on BSD it is an int, and in
|
|
dnl POSIX 1g it is a type of its own, but some platforms use different
|
|
dnl types for the argument to getsockopt, getpeername, etc. So we
|
|
dnl have to test to find something that will work.
|
|
AC_DEFUN([gl_TYPE_SOCKLEN_T],
|
|
[AC_CHECK_TYPE([socklen_t], ,
|
|
[AC_MSG_CHECKING([for socklen_t equivalent])
|
|
AC_CACHE_VAL([gl_cv_gl_cv_socklen_t_equiv],
|
|
[# Systems have either "struct sockaddr *" or
|
|
# "void *" as the second argument to getpeername
|
|
gl_cv_socklen_t_equiv=
|
|
for arg2 in "struct sockaddr" void; do
|
|
for t in int size_t "unsigned int" "long int" "unsigned long int"; do
|
|
AC_TRY_COMPILE(
|
|
[#include <sys/types.h>
|
|
#include <sys/socket.h>
|
|
|
|
int getpeername (int, $arg2 *, $t *);],
|
|
[$t len;
|
|
getpeername (0, 0, &len);],
|
|
[gl_cv_socklen_t_equiv="$t"])
|
|
test "$gl_cv_socklen_t_equiv" != "" && break
|
|
done
|
|
test "$gl_cv_socklen_t_equiv" != "" && break
|
|
done
|
|
])
|
|
if test "$gl_cv_socklen_t_equiv" = ""; then
|
|
AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
|
|
fi
|
|
AC_MSG_RESULT([$gl_cv_socklen_t_equiv])
|
|
AC_DEFINE_UNQUOTED([socklen_t], [$gl_cv_socklen_t_equiv],
|
|
[type to use in place of socklen_t if not defined])],
|
|
[#include <sys/types.h>
|
|
#include <sys/socket.h>])])
|