mirror of
git://git.sv.gnu.org/coreutils.git
synced 2026-04-20 10:51:48 +02:00
dfc5ff02a0
so that automake automatically knows to distribute those files. Use AC_LIBOBJ to ensure that automake automatically knows the names of always-compiled source files. Automake already knows the names of conditionally compiled ones, e.g., due to preexisting uses of AC_LIBOBJ and AC_REPLACE_FUNCS. [This is a start. Many still remain to be fixed...]
40 lines
1.3 KiB
Plaintext
40 lines
1.3 KiB
Plaintext
# getpass.m4 serial 6
|
|
dnl Copyright (C) 2002-2003, 2005 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
# Provide a getpass() function if the system doesn't have it.
|
|
AC_DEFUN([gl_FUNC_GETPASS],
|
|
[
|
|
AC_REPLACE_FUNCS(getpass)
|
|
AC_CHECK_DECLS_ONCE(getpass)
|
|
if test $ac_cv_func_getpass = no; then
|
|
gl_PREREQ_GETPASS
|
|
fi
|
|
])
|
|
|
|
# Provide the GNU getpass() implementation. It supports passwords of
|
|
# arbitrary length (not just 8 bytes as on HP-UX).
|
|
AC_DEFUN([gl_FUNC_GETPASS_GNU],
|
|
[
|
|
AC_LIBSOURCES([getpass.c, getpass.h])
|
|
|
|
AC_CHECK_DECLS_ONCE(getpass)
|
|
dnl TODO: Detect when GNU getpass() is already found in glibc.
|
|
AC_LIBOBJ(getpass)
|
|
gl_PREREQ_GETPASS
|
|
dnl We must choose a different name for our function, since on ELF systems
|
|
dnl an unusable getpass() in libc.so would override our getpass() if it is
|
|
dnl compiled into a shared library.
|
|
AC_DEFINE([getpass], [gnu_getpass],
|
|
[Define to a replacement function name for getpass().])
|
|
])
|
|
|
|
# Prerequisites of lib/getpass.c.
|
|
AC_DEFUN([gl_PREREQ_GETPASS], [
|
|
AC_CHECK_HEADERS_ONCE(stdio_ext.h)
|
|
AC_CHECK_DECLS_ONCE([fflush_unlocked flockfile fputs_unlocked funlockfile putc_unlocked])
|
|
:
|
|
])
|