mirror of
https://github.com/vim/vim.git
synced 2026-07-10 21:07:22 +02:00
Christian Brabandt
1f33732613
Normalize the 15 existing guards to the documented two-level form get(g:, 'X_recommended_style', get(g:, 'filetype_recommended_style', 1)): fix the two non-standard "!exists() || != 0" guards (python, arduino) and tolk's wrong fallback variable, and convert the simple one-level guards. Add the guard to filetype plugins that set stylistic indentation/format options without one: aap, abap, ada, cabal, cobol, elixir, falcon, graphql, heex, idris2, mermaid, occam, racket, scala, swift, tera. Settings that are required rather than stylistic are left untouched, e.g. make/gomod/scdoc (mandatory tabs), chatito and vroom (indent mandated by the format), and the textwidth/formatoptions cases in gitcommit/help/ jjdescription. Supported by AI. fixes: #20036 closes: #20650 Co-Authored-By: Claude Opus 4.8 (1M context) <noreply@anthropic.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
67 lines
1.9 KiB
VimL
67 lines
1.9 KiB
VimL
vim9script
|
|
|
|
# Vim filetype plugin file
|
|
# Language: gdscript (Godot game engine scripting language)
|
|
# Maintainer: Maxim Kim <habamax@gmail.com>
|
|
# Website: https://github.com/habamax/vim-gdscript
|
|
# Last Change: 2024 Jul 14
|
|
# 2026 Jun 27 by Vim Project (normalize recommended style guard)
|
|
|
|
if exists("b:did_ftplugin") | finish | endif
|
|
|
|
b:did_ftplugin = 1
|
|
b:undo_ftplugin = 'setlocal cinkeys<'
|
|
\ .. '| setlocal indentkeys<'
|
|
\ .. '| setlocal commentstring<'
|
|
\ .. '| setlocal suffixesadd<'
|
|
\ .. '| setlocal foldexpr<'
|
|
\ .. '| setlocal foldignore<'
|
|
|
|
setlocal cinkeys-=0#
|
|
setlocal indentkeys-=0#
|
|
setlocal suffixesadd=.gd
|
|
setlocal commentstring=#\ %s
|
|
setlocal foldignore=
|
|
setlocal foldexpr=GDScriptFoldLevel()
|
|
|
|
if get(g:, 'gdscript_recommended_style', get(g:, 'filetype_recommended_style', 1))
|
|
setlocal noexpandtab tabstop=4 softtabstop=0 shiftwidth=0
|
|
b:undo_ftplugin ..= ' | setlocal expandtab< tabstop< softtabstop< shiftwidth<'
|
|
endif
|
|
|
|
|
|
def GDScriptFoldLevel(): string
|
|
var line = getline(v:lnum)
|
|
if line =~? '^\s*$'
|
|
return "-1"
|
|
endif
|
|
|
|
var sw = shiftwidth()
|
|
var indent = indent(v:lnum) / sw
|
|
var indent_next = indent(nextnonblank(v:lnum + 1)) / sw
|
|
|
|
if indent_next > indent && line =~ ':\s*$'
|
|
return $">{indent_next}"
|
|
else
|
|
return $"{indent}"
|
|
endif
|
|
enddef
|
|
|
|
|
|
if !exists("g:no_plugin_maps")
|
|
# Next/Previous section
|
|
def NextSection(back: bool, cnt: number)
|
|
for n in range(cnt)
|
|
search('^\s*func\s', back ? 'bW' : 'W')
|
|
endfor
|
|
enddef
|
|
|
|
nnoremap <silent><buffer> ]] <scriptcmd>NextSection(false, v:count1)<CR>
|
|
nnoremap <silent><buffer> [[ <scriptcmd>NextSection(true, v:count1)<CR>
|
|
xmap <buffer><expr> ]] $'<C-\><C-N>{v:count1}]]m>gv'
|
|
xmap <buffer><expr> [[ $'<C-\><C-N>{v:count1}[[m>gv'
|
|
b:undo_ftplugin ..=
|
|
\ " | silent exe 'unmap <buffer> [['"
|
|
\ .. " | silent exe 'unmap <buffer> ]]'"
|
|
endif
|