mirror of
https://github.com/vim/vim.git
synced 2026-07-08 12:01:54 +02:00
Christian Brabandt
1f33732613
Normalize the 15 existing guards to the documented two-level form get(g:, 'X_recommended_style', get(g:, 'filetype_recommended_style', 1)): fix the two non-standard "!exists() || != 0" guards (python, arduino) and tolk's wrong fallback variable, and convert the simple one-level guards. Add the guard to filetype plugins that set stylistic indentation/format options without one: aap, abap, ada, cabal, cobol, elixir, falcon, graphql, heex, idris2, mermaid, occam, racket, scala, swift, tera. Settings that are required rather than stylistic are left untouched, e.g. make/gomod/scdoc (mandatory tabs), chatito and vroom (indent mandated by the format), and the textwidth/formatoptions cases in gitcommit/help/ jjdescription. Supported by AI. fixes: #20036 closes: #20650 Co-Authored-By: Claude Opus 4.8 (1M context) <noreply@anthropic.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
47 lines
1.4 KiB
VimL
47 lines
1.4 KiB
VimL
" Vim filetype plugin file
|
|
" Language: meson
|
|
" License: VIM License
|
|
" Maintainer: Liam Beguin <liambeguin@gmail.com>
|
|
" Original Author: Laurent Pinchart <laurent.pinchart@ideasonboard.com>
|
|
" Last Change: 2018 Nov 27
|
|
" 2024 Jan 14 by Vim Project (browsefilter)
|
|
" 2026 Jun 27 by Vim Project (normalize recommended style guard)
|
|
|
|
if exists("b:did_ftplugin") | finish | endif
|
|
let b:did_ftplugin = 1
|
|
let s:keepcpo= &cpo
|
|
set cpo&vim
|
|
|
|
setlocal commentstring=#\ %s
|
|
setlocal comments=:#
|
|
setlocal formatoptions+=croql formatoptions-=t
|
|
|
|
let b:undo_ftplugin = "setl com< cms< fo<"
|
|
|
|
if get(g:, 'meson_recommended_style',
|
|
\ get(g:, 'filetype_recommended_style', 1))
|
|
setlocal expandtab
|
|
setlocal shiftwidth=2
|
|
setlocal softtabstop=2
|
|
let b:undo_ftplugin .= " | setl et< sts< sw<"
|
|
endif
|
|
|
|
if exists("loaded_matchit") && !exists("b:match_words")
|
|
let b:match_words = '\<if\>:\<elif\>:\<else\>:\<endif\>,' .
|
|
\ '\<foreach\>:\<break\>:\<continue\>:\<endforeach\>'
|
|
let b:undo_ftplugin .= " | unlet! b:match_words"
|
|
endif
|
|
|
|
if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
|
|
let b:browsefilter = "Meson Build Files (meson.build)\tmeson.build\n"
|
|
if has("win32")
|
|
let b:browsefilter .= "All Files (*.*)\t*\n"
|
|
else
|
|
let b:browsefilter .= "All Files (*)\t*\n"
|
|
endif
|
|
let b:undo_ftplugin .= " | unlet! b:browsefilter"
|
|
endif
|
|
|
|
let &cpo = s:keepcpo
|
|
unlet s:keepcpo
|