mirror of
https://github.com/vim/vim.git
synced 2026-07-09 20:45:13 +02:00
Christian Brabandt
1f33732613
Normalize the 15 existing guards to the documented two-level form get(g:, 'X_recommended_style', get(g:, 'filetype_recommended_style', 1)): fix the two non-standard "!exists() || != 0" guards (python, arduino) and tolk's wrong fallback variable, and convert the simple one-level guards. Add the guard to filetype plugins that set stylistic indentation/format options without one: aap, abap, ada, cabal, cobol, elixir, falcon, graphql, heex, idris2, mermaid, occam, racket, scala, swift, tera. Settings that are required rather than stylistic are left untouched, e.g. make/gomod/scdoc (mandatory tabs), chatito and vroom (indent mandated by the format), and the textwidth/formatoptions cases in gitcommit/help/ jjdescription. Supported by AI. fixes: #20036 closes: #20650 Co-Authored-By: Claude Opus 4.8 (1M context) <noreply@anthropic.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
94 lines
2.8 KiB
VimL
94 lines
2.8 KiB
VimL
" Vim filetype plugin
|
|
" Language: Racket
|
|
" Maintainer: D. Ben Knoble <ben.knoble+github@gmail.com>
|
|
" Previous Maintainer: Will Langstroth <will@langstroth.com>
|
|
" URL: https://github.com/benknoble/vim-racket
|
|
" Last Change: 2025 Aug 09
|
|
" 2026 Mar 31 by Vim project: use shellescape for the K mapping
|
|
" 2026 Apr 01 by Vim project: make K mapping more robust for shell injection
|
|
" 2026 Jun 27 by Vim Project: add recommended style guard
|
|
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
let b:did_ftplugin = 1
|
|
|
|
let s:cpo_save = &cpo
|
|
set cpo&vim
|
|
|
|
" quick hack to allow adding values
|
|
setlocal iskeyword=@,!,#-',*-:,<-Z,a-z,~,_,94
|
|
|
|
if get(g:, 'racket_recommended_style',
|
|
\ get(g:, 'filetype_recommended_style', 1))
|
|
setlocal shiftwidth=2 softtabstop=2
|
|
endif
|
|
|
|
" Enable auto begin new comment line when continuing from an old comment line
|
|
setlocal comments=:;;;;,:;;;,:;;,:;
|
|
setlocal formatoptions+=r
|
|
|
|
setlocal commentstring=;;\ %s
|
|
|
|
setlocal formatprg=raco\ fmt
|
|
|
|
" Undo our settings when the filetype changes away from Racket
|
|
" (this should be amended if settings/mappings are added above!)
|
|
let b:undo_ftplugin =
|
|
\ "setlocal iskeyword< shiftwidth< softtabstop< comments< formatoptions< formatprg<"
|
|
\. " | setlocal commentstring<"
|
|
|
|
if !exists("no_plugin_maps") && !exists("no_racket_maps")
|
|
" Simply setting keywordprg like this works:
|
|
" setlocal keywordprg=raco\ docs
|
|
" but then vim says:
|
|
" "press ENTER or type a command to continue"
|
|
" We avoid the annoyance of having to hit enter by remapping K directly.
|
|
function s:RacketDoc(word) abort
|
|
execute 'silent !raco docs --' shellescape(a:word, v:true)
|
|
redraw!
|
|
endfunction
|
|
nnoremap <buffer> <Plug>RacketDoc :call <SID>RacketDoc(expand('<cword>'))<CR>
|
|
nmap <buffer> K <Plug>RacketDoc
|
|
|
|
" For the visual mode K mapping, it's slightly more convoluted to get the
|
|
" selected text:
|
|
function! s:Racket_visual_doc()
|
|
try
|
|
let l:old_a = @a
|
|
normal! gv"ay
|
|
call system("raco docs -- ". string(shellescape(@a)))
|
|
redraw!
|
|
return @a
|
|
finally
|
|
let @a = l:old_a
|
|
endtry
|
|
endfunction
|
|
|
|
xnoremap <buffer> <Plug>RacketDoc :call <SID>Racket_visual_doc()<cr>
|
|
xmap <buffer> K <Plug>RacketDoc
|
|
|
|
let b:undo_ftplugin .=
|
|
\ " | silent! execute 'nunmap <buffer> K'"
|
|
\. " | silent! execute 'xunmap <buffer> K'"
|
|
endif
|
|
|
|
if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
|
|
let b:browsefilter =
|
|
\ "Racket Source Files (*.rkt, *.rktl)\t*.rkt;*.rktl\n"
|
|
if has("win32")
|
|
let b:browsefilter .= "All Files (*.*)\t*\n"
|
|
else
|
|
let b:browsefilter .= "All Files (*)\t*\n"
|
|
endif
|
|
let b:undo_ftplugin .= " | unlet! b:browsefilter"
|
|
endif
|
|
|
|
if exists("loaded_matchit") && !exists("b:match_words")
|
|
let b:match_words = '#|:|#'
|
|
let b:undo_ftplugin .= " | unlet! b:match_words"
|
|
endif
|
|
|
|
let &cpo = s:cpo_save
|
|
unlet s:cpo_save
|