mirror of
https://github.com/vim/vim.git
synced 2026-07-07 02:51:00 +02:00
Christian Brabandt
1f33732613
Normalize the 15 existing guards to the documented two-level form get(g:, 'X_recommended_style', get(g:, 'filetype_recommended_style', 1)): fix the two non-standard "!exists() || != 0" guards (python, arduino) and tolk's wrong fallback variable, and convert the simple one-level guards. Add the guard to filetype plugins that set stylistic indentation/format options without one: aap, abap, ada, cabal, cobol, elixir, falcon, graphql, heex, idris2, mermaid, occam, racket, scala, swift, tera. Settings that are required rather than stylistic are left untouched, e.g. make/gomod/scdoc (mandatory tabs), chatito and vroom (indent mandated by the format), and the textwidth/formatoptions cases in gitcommit/help/ jjdescription. Supported by AI. fixes: #20036 closes: #20650 Co-Authored-By: Claude Opus 4.8 (1M context) <noreply@anthropic.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
44 lines
1.2 KiB
VimL
44 lines
1.2 KiB
VimL
" Vim filetype plugin file
|
|
" Language: YAML (YAML Ain't Markup Language)
|
|
" Previous Maintainer: Nikolai Weibull <now@bitwi.se> (inactive)
|
|
" Last Change: 2024 Oct 04
|
|
" 2025 Apr 22 by Vim project re-order b:undo_ftplugin (#17179)
|
|
" 2026 Jun 27 by Vim Project normalize recommended style guard
|
|
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
let b:did_ftplugin = 1
|
|
|
|
let s:cpo_save = &cpo
|
|
set cpo&vim
|
|
|
|
let b:undo_ftplugin = "setl com< cms< et< fo<"
|
|
|
|
setlocal comments=:# commentstring=#\ %s expandtab
|
|
setlocal formatoptions-=t formatoptions+=croql
|
|
|
|
if get(g:, 'yaml_recommended_style',
|
|
\ get(g:, 'filetype_recommended_style', 1))
|
|
let b:undo_ftplugin ..= " sw< sts<"
|
|
setlocal shiftwidth=2 softtabstop=2
|
|
endif
|
|
|
|
" rime input method engine(https://rime.im/)
|
|
" uses `*.custom.yaml` as its config files
|
|
if expand('%:r:e') ==# 'custom'
|
|
" `__include` command in `*.custom.yaml`
|
|
" see: https://github.com/rime/home/wiki/Configuration#%E5%8C%85%E5%90%AB
|
|
setlocal include=__include:\\s*
|
|
let b:undo_ftplugin ..= " inc<"
|
|
|
|
if !exists('current_compiler')
|
|
compiler rime_deployer
|
|
let b:undo_ftplugin ..= " | compiler make"
|
|
endif
|
|
endif
|
|
|
|
|
|
let &cpo = s:cpo_save
|
|
unlet s:cpo_save
|