mirror of
https://github.com/vim/vim.git
synced 2026-05-26 20:17:35 +02:00
Christian Brabandt
b0905e269d
Problem: tests: too many imports in the test suite Solution: Clean up the imported scripts Most tests make use of check.vim, so let's just source it once in runtest.vim instead of having each test manually source it. runtest.vim already sources shared.vim, which again sources view_util.vim, so we don't need to source those two common dependencies in all the other tests And then check.vim sources term_util.vim already, so we can in addition drop sourcing it explicitly in each single test script. Note: test_expand_func.vim had to be updated to account for the changed number of sourced files. And finally check.vim uses line-continuation so let's also explicitly enable line continuation via the 'cpo' option value. related: #17677 Signed-off-by: Christian Brabandt <cb@256bit.org>
118 lines
3.9 KiB
VimL
118 lines
3.9 KiB
VimL
" Test :suspend
|
|
|
|
func CheckSuspended(buf, fileExists)
|
|
call WaitForAssert({-> assert_match('[$#] $', term_getline(a:buf, '.'))})
|
|
|
|
if a:fileExists
|
|
call assert_equal(['foo'], readfile('Xfoo'))
|
|
else
|
|
" Without 'autowrite', buffer should not be written.
|
|
call assert_equal(0, filereadable('Xfoo'))
|
|
endif
|
|
|
|
call term_sendkeys(a:buf, "fg\<CR>\<C-L>")
|
|
call WaitForAssert({-> assert_equal(' 1 foo', term_getline(a:buf, '.'))})
|
|
endfunc
|
|
|
|
func Test_suspend()
|
|
CheckFeature terminal
|
|
CheckExecutable /bin/sh
|
|
|
|
" Somehow the modifyOtherKeys response may get to the terminal when using
|
|
" Mac OS. Make t_RK and 'keyprotocol' empty to avoid that.
|
|
set t_RK= keyprotocol=
|
|
|
|
call WaitForResponses()
|
|
|
|
let buf = term_start('/bin/sh')
|
|
" Wait for shell prompt.
|
|
call WaitForAssert({-> assert_match('[$#] $', term_getline(buf, '.'))})
|
|
|
|
call term_sendkeys(buf, v:progpath
|
|
\ . " --clean -X"
|
|
\ . " -c 'set nu keyprotocol='"
|
|
\ . " -c 'call setline(1, \"foo\")'"
|
|
\ . " Xfoo\<CR>")
|
|
" Cursor in terminal buffer should be on first line in spawned vim.
|
|
call WaitForAssert({-> assert_equal(' 1 foo', term_getline(buf, '.'))})
|
|
|
|
for suspend_cmd in [":suspend\<CR>",
|
|
\ ":stop\<CR>",
|
|
\ ":suspend!\<CR>",
|
|
\ ":stop!\<CR>",
|
|
\ "\<C-Z>"]
|
|
" Suspend and wait for shell prompt.
|
|
call term_sendkeys(buf, suspend_cmd)
|
|
call CheckSuspended(buf, 0)
|
|
endfor
|
|
|
|
" Test that :suspend! with 'autowrite' writes content of buffers if modified.
|
|
call term_sendkeys(buf, ":set autowrite\<CR>")
|
|
call assert_equal(0, filereadable('Xfoo'))
|
|
call term_sendkeys(buf, ":suspend\<CR>")
|
|
" Wait for shell prompt.
|
|
call CheckSuspended(buf, 1)
|
|
|
|
" Quit gracefully to dump coverage information.
|
|
call term_sendkeys(buf, ":qall!\<CR>")
|
|
call TermWait(buf)
|
|
" Wait until Vim actually exited and shell shows a prompt
|
|
call WaitForAssert({-> assert_match('[$#] $', term_getline(buf, '.'))})
|
|
call StopShellInTerminal(buf)
|
|
|
|
exe buf . 'bwipe!'
|
|
call delete('Xfoo')
|
|
endfunc
|
|
|
|
func Test_suspend_autocmd()
|
|
CheckFeature terminal
|
|
CheckExecutable /bin/sh
|
|
|
|
" Somehow the modifyOtherKeys response may get to the terminal when using
|
|
" Mac OS. Make t_RK and 'keyprotocol' empty to avoid that.
|
|
set t_RK= keyprotocol=
|
|
|
|
call WaitForResponses()
|
|
|
|
let buf = term_start('/bin/sh', #{term_rows: 6})
|
|
" Wait for shell prompt.
|
|
call WaitForAssert({-> assert_match('[$#] $', term_getline(buf, '.'))})
|
|
|
|
call term_sendkeys(buf, v:progpath
|
|
\ . " --clean -X"
|
|
\ . " -c 'set nu keyprotocol='"
|
|
\ . " -c 'let g:count = 0'"
|
|
\ . " -c 'au VimSuspend * let g:count += 1'"
|
|
\ . " -c 'au VimResume * let g:count += 1'"
|
|
\ . " -c 'call setline(1, \"foo\")'"
|
|
\ . " Xfoo\<CR>")
|
|
" Cursor in terminal buffer should be on first line in spawned vim.
|
|
call WaitForAssert({-> assert_equal(' 1 foo', term_getline(buf, '.'))})
|
|
|
|
for suspend_cmd in [":suspend\<CR>",
|
|
\ ":stop\<CR>",
|
|
\ ":suspend!\<CR>",
|
|
\ ":stop!\<CR>",
|
|
\ "\<C-Z>"]
|
|
" Suspend and wait for shell prompt. Then "fg" will restore Vim.
|
|
call term_sendkeys(buf, suspend_cmd)
|
|
call CheckSuspended(buf, 0)
|
|
endfor
|
|
|
|
call term_sendkeys(buf, ":echo g:count\<CR>")
|
|
call TermWait(buf)
|
|
call WaitForAssert({-> assert_match('^10', term_getline(buf, 6))})
|
|
|
|
" Quit gracefully to dump coverage information.
|
|
call term_sendkeys(buf, ":qall!\<CR>")
|
|
call TermWait(buf)
|
|
" Wait until Vim actually exited and shell shows a prompt
|
|
call WaitForAssert({-> assert_match('[$#] $', term_getline(buf, '.'))})
|
|
call StopShellInTerminal(buf)
|
|
|
|
exe buf . 'bwipe!'
|
|
call delete('Xfoo')
|
|
endfunc
|
|
|
|
" vim: shiftwidth=2 sts=2 expandtab
|